Stanza Query

提供：TogoWiki

metagenome_cross_reference スタンザ

そのメタゲノム/メタ16Sサンプルの他DBへのLink情報
※FROMのグラフ名を適宜変更して下さい

PREFIX msv: <http://purl.jp/bio/11/msv/>
PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>

SELECT ?label ?ID
FROM <http://localhost:8890/DAV/msv_130822_1.owl>
FROM <http://localhost:8890/DAV/srs_id_mapping_130827.ttl>
WHERE
{
	srs:ERS000862	?MSVterm ?ID.
	?MSVterm	rdfs:label	?label.

}ORDER BY ?label

実行結果

metagenome sequencing attributes スタンザ

そのメタゲノム/メタ16Sサンプルのシーケンシング情報
※FROMのグラフ名を適宜変更して下さい

PREFIX msv: <http://purl.jp/bio/11/msv/>
PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>

SELECT 
(SUM(?totalBasesInteger) AS ?totalBasesSum)
(SUM(?readNumberInteger) AS ?readNumberSum)
FROM <http://localhost:8890/DAV/msv_130822_1.owl>
FROM <http://localhost:8890/DAV/srs_id_mapping_130827.ttl>

WHERE
{
	srs:ERS000862	?MSVterm ?ID.
	?ID	msv:totalBases	?totalBases.
	?ID	msv:readNumber	?readNumber.
	BIND ( xsd:integer(?totalBases) AS ?totalBasesInteger )
	BIND ( xsd:integer(?readNumber) AS ?readNumberInteger )
}

実行結果

metagenome sample attributes スタンザ

そのメタゲノム/メタ16Sサンプルの基本情報
※FROMのグラフ名を適宜変更して下さい
※論文から抽出したメタデータ（srs_msv_journal_env.ttl / srs_msv_journal_human.ttl）も含めて検索すると項目が重複する問題があるため、使用するか議論中です。

PREFIX msv: <http://purl.jp/bio/11/msv/>
PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>
SELECT ?metadata_category ?metadata_value ?units

FROM <http://localhost:8890/DAV/srs_msv_130821.ttl>
#FROM <http://localhost:8890/DAV/srs_msv_journal_env.ttl>
#FROM <http://localhost:8890/DAV/srs_msv_journal_human.ttl>
FROM <http://localhost:8890/DAV/msv_130822_1.owl>
WHERE{
	srs:ERS000862	?MSVterm	?blank.
	?MSVterm	rdfs:label	?label.
	OPTIONAL{
		?blank	msv:value	?value.
		?blank	msv:units	?units.
	}
	OPTIONAL {
		?blank msv:tag	?tag.
	}
	BIND ( COALESCE ( ?tag, ?label ) AS ?metadata_category )
	BIND ( COALESCE ( ?value, ?blank ) AS ?metadata_value )
}ORDER BY ( ?metadata_category )

実行結果