BH12.12/stanza titech/Pathogen Information

提供：TogoWiki

2013年5月31日 (金) 02:16時点における版 (ソースを表示) Nozomy (トーク | 投稿記録) (→Pathogen information from symptom) ←古い編集		2013年5月31日 (金) 05:19時点における最新版 (ソースを表示) Nozomy (トーク | 投稿記録) (→Pathogen information from disease)
142行：		142行：
	*メモ----------------------------------		*メモ----------------------------------
	*SPARQL query--------------------------		*SPARQL query--------------------------
-	例：Phenumonia（pdo:PDO_000193）に関連する菌株情報の表示	+	例：Pneumonia（pdo:PDO_000193）に関連する菌株情報の表示
	<pre>		<pre>
	prefix pdo: <http://purl.jp/bio/11/pdo/>		prefix pdo: <http://purl.jp/bio/11/pdo/>

---

2013年5月31日 (金) 05:19時点における最新版

Pathogen information from phylogeny

• スタンザ概要--------------------------

  系統から関連する菌株と病名を表示する

• 入力----------------------------------

  NCBItaxID

• 出力----------------------------------

変数名	説明	URI or literal
NCBItaxID	NCBItaxIDのURI	URI
?bacterialName	菌株名	literal
?diseaseNameSet	病名セット	literal
?infectiousType	日和見感染かどうか	literal
?strainType	無毒株かどうか	literal

• 使用グラフ----------------------------

  PDO_ver0.1.owl （5/31修正）

  CSSO_ver0.1.owl

  mapping_ver2.ttl

  NCBI

• メモ----------------------------------

株名そのものを入れた場合にも対応します 例：Haemophilus influenzae 86-028NP（ncbitaxon:NCBITaxon_281310）など

• SPARQL query--------------------------

例：Mycobacterium（ncbitaxon:NCBITaxon_1763）の系統に属する、病気に関連する菌株情報の表示

prefix pdo: <http://purl.jp/bio/11/pdo/> 
prefix csso: <http://purl.jp/bio/11/csso/> 
prefix ncbitaxon: <http://purl.obolibrary.org/obo/>

SELECT ?bacterialName ?diseaseNameSet  ?infectiousType ?strainType 

FROM  <http://localhost:8890/PDO/test/mapping_ver2.ttl>
FROM  <http://localhost:8890/PDO/test/PDO_ver0.1.owl>
FROM  <http://localhost:8890/PDO/test/CSSO_ver0.1.owl>
FROM  <http://purl.org/obo/owl/NCBITaxon#>
WHERE{
{
	{SELECT DISTINCT ?NCBI ?bacterialName  (GROUP_CONCAT(?diseaseName; SEPARATOR = ",") AS ?diseaseNameSet)  
	WHERE{
		{?NCBI rdfs:subClassOf+ ncbitaxon:NCBITaxon_1763.
		?NCBI pdo:isAssociatedTo ?blanknode.
		?blanknode pdo:mayCaused ?disease.
		?disease rdfs:label ?diseaseName.
		?NCBI rdfs:label ?bacterialName.
		} UNION {
		?NCBI rdfs:subClassOf+ ncbitaxon:NCBITaxon_1763.
		?NCBI pdo:isAssociatedTo ?blanknode.
		?blanknode pdo:isRelatedTo ?disease.
		?disease rdfs:label ?diseaseName.
		?NCBI rdfs:label ?bacterialName.
		} 
		}}
			OPTIONAL{
			?NCBI pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:infectiousType ?infectiousType.
			}
			OPTIONAL{
			?NCBI pdo:isAssociatedTo ?blanknode2.
			?blanknode2 pdo:strainType ?strainType.
			}

} UNION {
	{SELECT DISTINCT ?bacterialName  (GROUP_CONCAT(?diseaseName; SEPARATOR = ",") AS ?diseaseNameSet)  
	WHERE{
		{ncbitaxon:NCBITaxon_1763 pdo:isAssociatedTo ?blanknode.
		?blanknode pdo:isRelatedTo ?disease.
		?disease rdfs:label ?diseaseName.
		ncbitaxon:NCBITaxon_1763 rdfs:label ?bacterialName.
		} UNION {
		ncbitaxon:NCBITaxon_1763 pdo:isAssociatedTo ?blanknode.
		?blanknode pdo:mayCaused ?disease.
		?disease rdfs:label ?diseaseName.
		ncbitaxon:NCBITaxon_1763 rdfs:label ?bacterialName.
		}
		}}
			OPTIONAL{
			ncbitaxon:NCBITaxon_1763 pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:infectiousType ?infectiousType.
			}
			OPTIONAL{
			ncbitaxon:NCBITaxon_1763 pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:strainType ?strainType.
			}
}
} 
ORDER BY ?bacterialName

実行結果

Pathogen information from disease

• スタンザ概要--------------------------

  病名から関連する菌株と関連情報を表示する

• 入力----------------------------------

  PDO_ID

• 出力----------------------------------

変数名	説明	URI or literal
PDO_ID	PDO IDのURI	URI
?bacterialName	菌株名	literal
?diseaseNameSet	病名セット	literal
?infectiousType	日和見感染かどうか	literal
?strainType	無毒株かどうか	literal
?speciesName	上位分類（種名）	literal

• 使用グラフ----------------------------

  PDO_ver0.1.owl（5/31修正）

  CSSO_ver0.1.owl

  mapping_ver2.ttl

  NCBI

• メモ----------------------------------
• SPARQL query--------------------------

例：Pneumonia（pdo:PDO_000193）に関連する菌株情報の表示

prefix pdo: <http://purl.jp/bio/11/pdo/> 
prefix csso: <http://purl.jp/bio/11/csso/> 
prefix ncbitaxon: <http://purl.obolibrary.org/obo/>
prefix ncbirank: <http://purl.obolibrary.org/obo/ncbitaxon#>

SELECT ?bacterialName ?diseaseNameSet  ?infectiousType ?strainType ?speciesName

FROM  <http://localhost:8890/PDO/test/mapping_ver2.ttl>
FROM  <http://localhost:8890/PDO/test/PDO_ver0.1.owl>
FROM  <http://localhost:8890/PDO/test/CSSO_ver0.1.owl>
FROM  <http://purl.org/obo/owl/NCBITaxon#>
WHERE{
	{SELECT DISTINCT ?NCBI ?bacterialName  (GROUP_CONCAT(?diseaseName; SEPARATOR = ",") AS ?diseaseNameSet)  ?speciesName
WHERE{
	{
	?blanknode pdo:mayCaused pdo:PDO_000193.
	?NCBI pdo:isAssociatedTo ?blanknode.
	?NCBI pdo:isAssociatedTo ?blanknode2.
	?blanknode2 pdo:mayCaused ?disease.
	?disease rdfs:label ?diseaseName.
	?NCBI rdfs:label ?bacterialName.
		OPTIONAL {
		?NCBI rdfs:subClassOf+ ?upperClass.
		?upperClass ncbirank:has_rank ncbitaxon:NCBITaxon_species.
		?upperClass rdfs:label ?speciesName.
		}
	}
	UNION
	{
	?blanknode pdo:isRelatedTo pdo:PDO_000193.
	?NCBI pdo:isAssociatedTo ?blanknode.
	?NCBI pdo:isAssociatedTo ?blanknode2.
	?blanknode2 pdo:isRelatedTo ?disease.
	?disease rdfs:label ?diseaseName.
	?NCBI rdfs:label ?bacterialName.
		OPTIONAL {
		?NCBI rdfs:subClassOf+ ?upperClass.
		?upperClass ncbirank:has_rank ncbitaxon:NCBITaxon_species.
		?upperClass rdfs:label ?speciesName.
		}
	}}}
OPTIONAL{
?blanknode pdo:infectiousType ?infectiousType.
?NCBI pdo:isAssociatedTo ?blanknode.
}
OPTIONAL{
?blanknode pdo:strainType ?strainType.
?NCBI pdo:isAssociatedTo ?blanknode.
}
}
ORDER BY ?bacterialName

実行結果

Pathogen information from symptom

• スタンザ概要--------------------------

  症状から関連する病名、菌株と関連情報を表示する

  PDO、CSSOどちらにも登録されている場合は分けて表示(菌株がだぶって表示される場合あり)

• 入力----------------------------------

  CSSO_ID (or PDO_ID)

• 出力----------------------------------

変数名	説明	URI or literal
CSSO_ID	CSSO IDのURI	URI
PDO_ID	PDO IDのURI	URI
?bacterialName	菌株名	literal
?diseaseNameSetFromSymptom	病名セット（症状で検索）	literal
?diseaseNameSetFromDisease	病名セット（病名で検索）	literal
?infectiousType	日和見感染かどうか	literal
?strainType	無毒株かどうか	literal

• 使用グラフ----------------------------

  PDO_ver0.1.owl（5/31修正）

  CSSO_ver0.1.owl

  mapping_ver2.ttl

  NCBI

• メモ----------------------------------
• SPARQL query--------------------------

例：Diarrhea（csso:CSSO_000102/pdo:PDO_000122）に関連する菌株情報の表示

prefix pdo: <http://purl.jp/bio/11/pdo/> 
prefix csso: <http://purl.jp/bio/11/csso/> 
prefix ncbitaxon: <http://purl.obolibrary.org/obo/>

SELECT ?bacterialName ?diseaseNameSetFromSymptom ?diseaseNameSetFromDisease ?opportunistic ?strainType 

FROM  <http://localhost:8890/PDO/test/mapping_ver2.ttl>
FROM  <http://localhost:8890/PDO/test/PDO_ver0.1.owl>
FROM  <http://localhost:8890/PDO/test/CSSO_ver0.1.owl>
FROM  <http://purl.org/obo/owl/NCBITaxon#>
WHERE{
	{
		{SELECT DISTINCT ?NCBI ?bacterialName  (GROUP_CONCAT(?diseaseNameFromSymptom; SEPARATOR = ",") AS ?diseaseNameSetFromSymptom)  
		WHERE{
		?disease pdo:hasSymptomOf csso:CSSO_000102.
			{?NCBI pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:mayCaused ?disease.
			?disease rdfs:label ?diseaseNameFromSymptom.
			} UNION { 
			?NCBI pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:isRelatedTo ?disease.
			?disease rdfs:label ?diseaseNameFromSymptom.
			}
		?NCBI rdfs:label ?bacterialName.
		}}
	} UNION {
		{SELECT DISTINCT ?NCBI ?bacterialName  (GROUP_CONCAT(?diseaseNameFromDisease; SEPARATOR = ",") AS ?diseaseNameSetFromDisease)  
		WHERE{
			{?NCBI pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:mayCaused pdo:PDO_000122.
			?blanknode pdo:mayCaused ?disease.
			?disease rdfs:label ?diseaseNameFromDisease.
			} UNION {
			?NCBI pdo:isAssociatedTo ?blanknode.
			?blanknode pdo:isRelatedTo pdo:PDO_000122.
			?blanknode pdo:isRelatedTo ?disease.
			?disease rdfs:label ?diseaseNameFromDisease.
			}
		?NCBI rdfs:label ?bacterialName.
		}}
	}
OPTIONAL{
?NCBI pdo:isAssociatedTo ?blanknode.
?blanknode pdo:infectiousType ?opportunistic.
}
OPTIONAL{
?NCBI pdo:isAssociatedTo ?blanknode3.
?blanknode3 pdo:strainType ?strainType.
}
}
ORDER by ?bacterialName

実行結果