SPARQLthon/ngs5 sparql tutorial

提供:TogoWiki

移動: 案内, 検索

NGS現場の会のチュートリアル用クエリ
エンドポイント: http://togogenome.org/sparql-ngs

2型糖尿病のClinVar変異一覧

medgenのコンセプトID:C0011860(MedGenDiabetes mellitus type 2)をキーにしてして変異情報をClinVarから検索

  • ClinVarの一覧を取得
PREFIX cvo: <http://purl.jp/bio/10/clinvar/>
PREFIX medgen: <http://identifiers.org/medgen/>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT DISTINCT ?clinvar ?clinvar_id ?clinvar_label
FROM <http://togogenome.org/variation/clinvar>
WHERE
{
  ?allele dcterms:references medgen:C0011860 .
  ?clinvar cvo:allele ?allele ;
    rdfs:label ?clinvar_label ;
    dcterms:identifier ?clinvar_id .
}
  • ClinVarのOPTIONAL項目を取得
PREFIX cvo: <http://purl.jp/bio/10/clinvar/>
PREFIX medgen: <http://identifiers.org/medgen/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX so: <http://purl.obolibrary.org/obo/so#>

SELECT DISTINCT ?clinvar ?clinvar_id ?clinvar_label ?review_status ?last_evaluated ?clinical_significance ?gene
FROM <http://togogenome.org/variation/clinvar>
WHERE
{
  ?allele dcterms:references medgen:C0011860 .
  ?clinvar cvo:allele ?allele ;
    rdfs:label ?clinvar_label ;
    dcterms:identifier ?clinvar_id .
  OPTIONAL { ?clinvar cvo:reviewStatus ?review_status . }
  OPTIONAL { ?clinvar dcterms:modified ?last_evaluated . }
  OPTIONAL { ?clinvar cvo:clinicalSignificance ?clinical_significance . }
  OPTIONAL { ?allele so:variant_of ?gene . }
}
  • HGNCのgene_idからUniProtIDを取得する
PREFIX cvo: <http://purl.jp/bio/10/clinvar/>
PREFIX medgen: <http://identifiers.org/medgen/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX so: <http://purl.obolibrary.org/obo/so#>

SELECT DISTINCT ?clinvar ?clinvar_label ?clinvar_id  ?review_status ?last_evaluated ?clinical_significance ?gene_id 
  (GROUP_CONCAT(DISTINCT REPLACE(STR(?uniprot_id),"http://purl.uniprot.org/uniprot/","") ; separator = ", ") AS ?uniprot_ids)
FROM <http://togogenome.org/variation/clinvar>
FROM <http://sparql.uniprot.org/uniprot>
WHERE
{
  ?allele dcterms:references medgen:C0011860 .
  ?clinvar cvo:allele ?allele ;
    rdfs:label ?clinvar_label ;
    dcterms:identifier ?clinvar_id .
  OPTIONAL { ?clinvar cvo:reviewStatus ?review_status . }
  OPTIONAL { ?clinvar dcterms:modified ?last_evaluated . }
  OPTIONAL { ?clinvar cvo:clinicalSignificance ?clinical_significance . }
  OPTIONAL {
   ?allele so:variant_of ?gene . 
    BIND (IRI(REPLACE(STR(?gene),"http://identifiers.org/hgnc/","http://purl.uniprot.org/hgnc/")) AS ?gene_id)
    SERVICE SILENT <http://sparql.uniprot.org/sparql> {   
      GRAPH <http://sparql.uniprot.org/uniprot> {
        ?uniprot_id rdfs:seeAlso ?gene_id
      }
    }
  }
} GROUP BY ?clinvar ?clinvar_label ?clinvar_id  ?review_status ?last_evaluated ?clinical_significance ?gene_id  
個人用ツール