BH12.12/stanza titech/metagenome sample list

提供:TogoWiki

移動: 案内, 検索

metagenome sample list / meta16S sample list

  • スタンザ概要--------------------------
    ある環境から採取されたメタゲノムサンプルのリスト
    ある環境から採取されたメタ16Sサンプルのリスト
  • 入力----------------------------------
    MEO_ID
  • 出力----------------------------------
変数名説明URI or literal
?SRS_titleSRS ID名literal
?SRS_labelSRSのタイトルliteral
?env_material_listSRSのenvironmental materialの列挙literal
?env_feature_listSRSのenvironmental featureの列挙literal
?biome_listSRSのbiomeの列挙literal
  • 使用グラフ----------------------------
    meo_sample.ttl.Changed3
  • メモ----------------------------------
    • 一つのメタゲノムサンプルに対して複数のFeature / Material / biomeタームが対応付いている時に、総当りで検索結果が返ってきてしまうのを防ぐため、以下のような3つのサブクエリをもつSPARQL文となった。
    • 全てのサンプルにFeature, Material, biomeタームやSRSのタイトルが対応付いているとは限らないので、OPTIONALで取得した。
    • メタゲノムサンプルなのかメタ16Sサンプルなのか の区別は後回し(ヒトメタゲノム関連論文からのメタデータ抽出の後)
  • SPARQL query--------------------------

例:メタデータにMEO_0000054(feces)を持つメタゲノムデータのリスト

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX srs: <http://trace.ncbi.nlm.nih.gov/Traces/sra/sra.cgi?sample=>
PREFIX envo: <http://purl.bioontology.org/ontology/ENVO/>
PREFIX gaz: <http://purl.org/obo/owl/GAZ#>
PREFIX fma: <http://sig.uw.edu/fma#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX ncbitaxon: <http://purl.org/obo/owl/NCBITaxon#>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT DISTINCT
?SRS_label ?SRS_title ?env_material_list ?env_feature_list ?biome_list 
WHERE{
	{
		SELECT ?SRS_ID (GROUP_CONCAT(?Material_label ; SEPARATOR = " , ")AS ?env_material_list)
		WHERE{
			?SRS_ID	meo:environmentalMaterial|meo:environmentalFeature|meo:biome	[
				dc:identifier	meo:MEO_0000054;
				rdfs:label	"feces" ;	
			] .
			OPTIONAL{
				?SRS_ID	 meo:environmentalMaterial	[
					dc:identifier	?environmentalMaterial;
					rdfs:label	?Material_label ;
				] .
			}
		}
	}
	{
		SELECT ?SRS_ID (GROUP_CONCAT(?Feature_label ; SEPARATOR = " , ")AS ?env_feature_list)
		WHERE{
			?SRS_ID	meo:environmentalMaterial|meo:environmentalFeature|meo:biome	[
				dc:identifier	meo:MEO_0000054;
				rdfs:label	"feces" ;	
			] .
			OPTIONAL{
				?SRS_ID	 meo:environmentalFeature	[
					dc:identifier	?environmentalFeature;
					rdfs:label	?Feature_label ;
				] .
			}
		}
	}
	{
		SELECT ?SRS_ID (GROUP_CONCAT(?biome_label ; SEPARATOR = " , ")AS ?biome_list)
		WHERE{
			?SRS_ID	meo:environmentalMaterial|meo:environmentalFeature|meo:biome	[
				dc:identifier	meo:MEO_0000054;
				rdfs:label	"feces" ;	
			] .
			OPTIONAL{
				?SRS_ID	 meo:biome	[
					dc:identifier	?biome;
					rdfs:label	?biome_label;
				] .
			}
		}
	}
	OPTIONAL{
		?SRS_ID	srs:TITLE	?SRS_title.
	}
	OPTIONAL{
		?SRS_ID	rdfs:label	?SRS_label.
	}
} ORDER BY ?SRS_label

実行結果

個人用ツール