BH12.12/StanzaQuery

提供:TogoWiki

移動: 案内, 検索

目次

Genome関連スタンザ

genome information スタンザ

あるゲノムが持つRepliconの基本情報、Replicon毎の遺伝子数等の統計情報、配列URLのリンク
クエリ例:Taxonomy ID :1148

DEFINE sql:select-option "order"
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX insdc: <http://insdc.org/owl/>
PREFIX idorg: <http://rdf.identifiers.org/database/>
PREFIX idtax: <http://identifiers.org/taxonomy/>

SELECT  ?bioproject ?bioproject_id ?refseq_version ?desc ?replicon_type ?sequence_length
 count(?gene_locus_tag) as ?gene_cnt 
 count(?trna_locus_tag) as ?trna_cnt 
 count(?rrna_locus_tag) as ?rrna_cnt
 count(?other_locus_tag) as ?other_cnt 
FROM <http://togogenome.org/refseq/>
FROM <http://togogenome.org/so/>
WHERE 
{ 
  ?seq rdfs:seeAlso idtax:1148 ;
    rdfs:label ?desc ;
    rdfs:seeAlso ?bioproject ;
    insdc:sequence_version ?refseq_version ;
    insdc:sequence_length ?sequence_length ;
    rdfs:seeAlso ?refseq_link ;
    a ?so FILTER (?so =  obo:SO_0000340 || ?so = obo:SO_0000155) .
  ?so rdfs:label ?replicon_type .
  ?bioproject a idorg:BioProject ;
    rdfs:label ?bioproject_id .
  ?refseq_link a idorg:RefSeq .
  {
    ?gene obo:so_part_of ?seq;
      a obo:SO_0000704 ;
      insdc:feature_locus_tag ?gene_locus_tag .
  }
  UNION
  {
    ?trna obo:so_part_of ?seq;
      a obo:SO_0000253 ;
    insdc:feature_locus_tag ?trna_locus_tag .
  }
  UNION
  {
    ?rrna obo:so_part_of ?seq;
      a obo:SO_0000252 ;
      insdc:feature_locus_tag ?rrna_locus_tag .
  }
 UNION
  {
    ?other obo:so_part_of ?seq;
      a ?obotype;
      insdc:feature_locus_tag ?other_locus_tag 
       FILTER (?obotype != obo:SO_0000704 &&  ?obotype != obo:SO_0000253 && ?obotype != obo:SO_0000252)  .
  }
}

実行結果
もっと項目を増やす場合の参考クエリ

replicon スタンザ (廃止)

内容が重複するのでgenome_informationスタンザと統合

genome_cross_reference スタンザ

あるゲノムの他DBへのLink情報

http://wiki.lifesciencedb.jp/mw/index.php/BH12.12/SPARQLthon8/TogoStanza#genome_cross_reference_stanza

Gene関連スタンザ

TaxonomyIDとLocusTagを指定するスタンザ

gene_attributes スタンザ

1株の1遺伝子の基本情報

DEFINE sql:select-option "order"
PREFIX obo:    <http://purl.obolibrary.org/obo/>
PREFIX faldo:  <http://biohackathon.org/resource/faldo#>
PREFIX idorg:  <http://rdf.identifiers.org/database/>
PREFIX insdc:  <http://insdc.org/owl/>
 
SELECT distinct ?locus_tag ?gene_type_label ?gene_symbol ?seq_label ?seq_type_label ?refseq_label ?organism ?ncbi_taxid 
  ?faldo_begin_position ?faldo_end_position ?stand
  concat("http://togows.dbcls.jp/entry/nucleotide/", replace(?refseq_label,"RefSeq:",""),"/seq/", ?insdc_location) as ?seqence
FROM <http://togogenome.org/refseq/>
FROM <http://togogenome.org/so/>
FROM <http://togogenome.org/faldo/>
WHERE
{
  values ?locus_tag {"slr0473"}
  values ?seq_type  { obo:SO_0000340 obo:SO_0000155 }
  values ?gene_type { obo:SO_0000704 obo:SO_0000252 obo:SO_0000253}
  values ?faldo_stand_type {faldo:ForwardStrandPosition faldo:ReverseStrandPosition}
     
  ?gene insdc:feature_locus_tag ?locus_tag ;
    a ?gene_type ;
    obo:so_part_of ?seq .
  OPTIONAL {?gene insdc:feature_gene ?gene_symbol.}
  ?gene_type rdfs:label ?gene_type_label .
  #sequence
  ?seq rdfs:label ?seq_label ;
    a ?seq_type ;
    rdfs:seeAlso ?refseq ;
    insdc:source_organism ?organism ;
    rdfs:seeAlso ?taxonomy .
  ?seq_type rdfs:label ?seq_type_label .
  ?refseq a idorg:RefSeq ;
    rdfs:label ?refseq_label .
  ?taxonomy a idorg:Taxonomy ;
    rdfs:label ?ncbi_taxid .
  #faldo
  ?gene faldo:location ?faldo .
  ?faldo insdc:location ?insdc_location ;
    faldo:begin ?faldo_begin ;
    faldo:end ?faldo_end .
  ?faldo_begin faldo:position ?faldo_begin_position ;
    rdf:type ?faldo_stand_type .
  ?faldo_end faldo:position ?faldo_end_position.
  ?faldo_stand_type rdfs:label ?stand
}

temp

PREFIX obo:    <http://purl.obolibrary.org/obo/>
PREFIX faldo:  <http://biohackathon.org/resource/faldo#>
PREFIX idorg:  <http://rdf.identifiers.org/database/>
PREFIX insdc:  <http://insdc.org/owl/>
 
SELECT count(?cds)
FROM <http://togogenome.org/refseq/>
WHERE
{    
  ?cds insdc:feature_locus_tag ?locus_tag ;
    a obo:SO_0000316 .
}

gene_sequence スタンザ

1株の1遺伝子の塩基配列情報

DEFINE sql:select-option "order"
PREFIX obo:    <http://purl.obolibrary.org/obo/>
PREFIX faldo:  <http://biohackathon.org/resource/faldo#>
PREFIX idorg:  <http://rdf.identifiers.org/database/>
PREFIX insdc:  <http://insdc.org/owl/>
 
SELECT distinct ?locus_tag 
  concat("http://togows.dbcls.jp/entry/nucleotide/", replace(?refseq_label,"RefSeq:",""),"/seq/", ?insdc_location) as ?seqence
FROM <http://togogenome.org/refseq/>
FROM <http://togogenome.org/so/>
WHERE
{
  values ?locus_tag {"all1455"}
  values ?seq_type  { obo:SO_0000340 obo:SO_0000155 }
  values ?gene_type { obo:SO_0000704 obo:SO_0000252 obo:SO_0000253}
     
  ?gene insdc:feature_locus_tag ?locus_tag ;
    a ?gene_type ;
    obo:so_part_of ?seq .
  ?seq a ?seq_type ;
    rdfs:seeAlso ?refseq .
  ?refseq a idorg:RefSeq ;
    rdfs:label ?refseq_label .
  ?gene faldo:location ?faldo .
  ?faldo insdc:location ?insdc_location .
}

gene_view スタンザ

遺伝子などの前後を含む可視化

DEFINE sql:select-option "order"

prefix rdf:    <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix rdfs:   <http://www.w3.org/2000/01/rdf-schema#>
prefix xsd:    <http://www.w3.org/2001/XMLSchema#>
prefix obo:    <http://purl.obolibrary.org/obo/>
prefix faldo:  <http://biohackathon.org/resource/faldo#>
prefix idorg:  <http://rdf.identifiers.org/database/>
prefix insdc:  <http://insdc.org/owl/>

select *
from <http://togogenome.org/refseq/>
from <http://togogenome.org/so/>
from <http://togogenome.org/faldo/>
where {
  values ?locus_tag { "slr0473" }  # param "slr0473"
  #values ?ncbi_taxid {"#{tax_id}" }  # param "taxon:1148"
  values ?seq_type  { obo:SO_0000340 obo:SO_0000155 } # chromosome, plasmid
  values ?gene_type { obo:SO_0000316 obo:SO_0000252 obo:SO_0000253 } # CDS, rRNA, tRNA
  values ?faldo_type { faldo:ForwardStrandPosition faldo:ReverseStrandPosition }
  values ?offset { 2000 }

  # gene
  ?gene insdc:feature_locus_tag ?locus_tag.
  ?gene a ?gene_type.

  # seq
  ?gene obo:so_part_of+ ?seq.
  ?seq a ?seq_type.

  # faldo
  ?gene faldo:location ?gene_loc.
  ?gene_loc faldo:begin/faldo:position ?gene_begin.
  ?gene_loc faldo:end/faldo:position ?gene_end.

  # taxonomy ncbi
  ?seq rdfs:seeAlso ?taxonomy .
  ?taxonomy a idorg:Taxonomy .
  ?taxonomy rdfs:label ?ncbi_taxid .

  # objects around the gene
  ?obj obo:so_part_of+ ?seq .

  ?obj faldo:location ?faldo .
  ?faldo faldo:begin/rdf:type ?faldo_type .
  ?faldo_type rdfs:label ?strand .
  ?faldo faldo:begin/faldo:position ?b .
  ?faldo faldo:end/faldo:position ?e .
  #bind ((xsd:integer(?gene_begin) - ?offset) as ?f)
  #bind ((xsd:integer(?gene_end) + ?offset) as ?t)
  #filter (!(?b > ?t || ?e < ?f))
  filter (!(?b > ?gene_end + ?offset || ?e < ?gene_begin - ?offset))

  ?obj rdf:type ?obj_type .
  ?obj_type rdfs:label ?obj_label .
  filter (?obj_type != obo:SO_0000704)  # gene
  optional {
    ?obj insdc:feature_locus_tag ?label .
  }
  optional {
    ?obj insdc:feature_product ?obj_name .
    #?obj insdc:feature_product|insdc:feature_gene ?obj_name .
  }
  #optional {
  #  ?obj rdfs:seeAlso ?obj_seealso .
  #}

  optional {
    ?obj obo:so_has_part/rdf:rest*/rdf:first ?part .
    ?part faldo:begin/faldo:position ?pb .
    ?part faldo:end/faldo:position ?pe .
  }
}
order by ?b

protein_ortholog スタンザ

1株の1タンパク質が所属するオーソログ情報


gene_cross_reference スタンザ

ある遺伝子のの他DBへのLink情報


Taxonomy関連スタンザ

TaxonomyIDを指定するスタンザ

organism_name スタンザ

ある系統の基本情報 (含む: organism_synonym - 種名変遷)

PREFIX go: <http://www.geneontology.org/formats/oboInOwl#>
PREFIX ncbitaxon: <http://purl.obolibrary.org/obo/NCBITaxon_>
PREFIX obotaxon: <http://purl.obolibrary.org/obo/ncbitaxon#>

SELECT ?name  ?name_type
FROM <http://togogenome.org/ncbitaxon/>
WHERE
{
  {
    SELECT ?name  ?name_type
    WHERE
    {
      ncbitaxon:1148 rdfs:label ?name .
      BIND("Scientific name" AS ?name_type)
    }
  }
  UNION
  {
    SELECT DISTINCT ?synonymTypeLabel AS ?name_type ?annotatedTarget AS ?name
    WHERE
    {
      ?blank owl:annotatedSource ncbitaxon:1148 ;
      owl:annotatedTarget ?annotatedTarget ;
      go:hasSynonymType ?synonymType 
      FILTER (?synonymType != obotaxon:misspelling) .
      ?synonymType rdfs:label ?synonymTypeLabel
    }
  }
}

新しいtaxo:owlでのクエリ
ORDER BY を指定すると、出力されるnameが異なる!

PREFIX taxo: <http://ddbj.nig.ac.jp/ontologies/taxonomy#>
PREFIX taxid: <http://identifiers.org/taxonomy/>

SELECT ?name ?name_type
FROM <http://togogenome.org/taxonomy/>
WHERE
{
 taxid:1148 ?p ?name .
 ?p rdfs:subPropertyOf taxo:name .
 ?p rdfs:label ?name_type
}#ORDER BY ?name_type

lineage_info スタンザ

ある系統のクラス階層と名前の対応表
上位層を辿る

PREFIX taxon: <http://purl.obolibrary.org/obo/NCBITaxon_>
 
SELECT
  REPLACE(STR(?tax) ,"http://purl.obolibrary.org/obo/NCBITaxon_" ,"" ) AS ?tax_no
  REPLACE(STR(?tax) ,"http://purl.obolibrary.org/obo/NCBITaxon_" ,"http://identifiers.org/taxonomy/" ) AS ?tax_link
  ?tax_label
  REPLACE(STR(?rank) ,"http://purl.obolibrary.org/obo/NCBITaxon_" ,"" ) AS ?rank
WHERE
{
  ?search_tax rdfs:label ?label FILTER (?search_tax = taxon:1148 ) .
  ?search_tax rdfs:subClassOf ?tax OPTION (transitive, t_direction 1, t_min(0), t_step("step_no") as ?step) .
  ?tax rdfs:label ?tax_label .
  OPTIONAL { ?tax <http://purl.obolibrary.org/obo/ncbitaxon#has_rank> ?rank . }
  FILTER(?tax != <http://purl.obolibrary.org/obo/NCBITaxon_1>)
} ORDER BY DESC(?step)

新しいtaxon.owl対応

PREFIX taxo: <http://ddbj.nig.ac.jp/ontologies/taxonomy#>
PREFIX taxid: <http://identifiers.org/taxonomy/>

SELECT
 REPLACE(STR(?tax) ,"http://identifiers.org/taxonomy/" ,"" ) AS ?tax_no
 ?tax AS ?tax_link
 ?tax_label
 REPLACE(STR(?rank) ,"http://ddbj.nig.ac.jp/ontologies/taxonomy#" ,"" ) AS ?rank
FROM <http://togogenome.org/taxonomy/>
WHERE
{
  ?search_tax rdfs:label ?o FILTER (?search_tax = taxid:1148 ) .
  ?search_tax rdfs:subClassOf ?tax OPTION (transitive, t_direction 1, t_min(0), t_step("step_no") as ?step) .
  ?tax rdfs:label ?tax_label .
  OPTIONAL { ?tax taxo:rank ?rank . }
  FILTER(?tax != taxid:1)
} ORDER BY DESC(?step)	


下位層を辿る(一回層のみ)

PREFIX taxon: <http://purl.obolibrary.org/obo/NCBITaxon_>

SELECT 
  REPLACE(STR(?tax) ,"http://purl.obolibrary.org/obo/NCBITaxon_" ,"" ) AS ?tax_no
  REPLACE(STR(?tax) ,"http://purl.obolibrary.org/obo/NCBITaxon_" ,"http://identifiers.org/taxonomy/" ) AS ?tax_link
  ?tax_label
  REPLACE(STR(?rank) ,"http://purl.obolibrary.org/obo/NCBITaxon_" ,"" ) AS ?rank
WHERE
{
  ?search_tax rdfs:label ?label FILTER (?search_tax = taxon:1148 ) .
  ?tax rdfs:subClassOf ?search_tax .
  ?tax rdfs:label ?tax_label .
  OPTIONAL { ?tax <http://purl.obolibrary.org/obo/ncbitaxon#has_rank> ?rank . }
} ORDER BY ?tax

新しいtaxon.owl対応

PREFIX taxo: <http://ddbj.nig.ac.jp/ontologies/taxonomy#>
PREFIX taxid: <http://identifiers.org/taxonomy/>

SELECT 
 REPLACE(STR(?tax) ,"http://identifiers.org/taxonomy/" ,"" ) AS ?tax_no
 ?tax AS ?tax_link
 ?tax_label
 REPLACE(STR(?rank) ,"http://ddbj.nig.ac.jp/ontologies/taxonomy#" ,"" ) AS ?rank
FROM <http://togogenome.org/taxonomy/>
WHERE
{
  ?search_tax rdfs:label ?label FILTER (?search_tax = taxid:1148 ) .
  ?tax rdfs:subClassOf ?search_tax .
  ?tax rdfs:label ?tax_label .
  OPTIONAL { ?tax taxo:rank ?rank . }
}

taxon_cross_referencee スタンザ

ある菌株の他DBへのLink情報
ひとつのエンドポイントからは取得できないので、複数にクエリを分ける

  • refseqからxrefデータを取得(genome_cross_reference_stanza)

http://wiki.lifesciencedb.jp/mw/index.php/BH12.12/SPARQLthon8/TogoStanza#genome_cross_reference_stanza

PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX  insdc: <http://insdc.org/owl/>
PREFIX  idtax: <http://identifiers.org/taxonomy/>

SELECT DISTINCT ?label ?xref
FROM <http://togogenome.org/refseq/>
WHERE
{
  values ?tax_id { idtax:1148 }
  values ?so { obo:SO_0000340 obo:SO_0000155 }
  ?seq rdfs:seeAlso ?tax_id .
  ?seq a ?so .
  ?seq rdfs:seeAlso ?xref .
  ?xref rdfs:label ?label .
} ORDER BY ?label
  • GOLDを取得
PREFIX mccv: <http://purl.jp/bio/01/mccv#>
PREFIX  idtax: <http://identifiers.org/taxonomy/>
 
SELECT REPLACE(str(?gold),"http://genomesonline.org/cgi-bin/GOLD/GOLDCards.cgi\\?goldstamp=", "GOLD:" ) as ?label ?gold as ?link 
FROM <http://togogenome.org/gold/>
WHERE 
{
  ?gold mccv:MCCV_000020 idtax:1148 .
}
  • 上の2つを結合
PREFIX mccv: <http://purl.jp/bio/01/mccv#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX  insdc: <http://insdc.org/owl/>
PREFIX  idtax: <http://identifiers.org/taxonomy/>

SELECT ?label ?link
FROM <http://togogenome.org/gold/>
FROM <http://togogenome.org/refseq/>
FROM <http://togogenome.org/ncbitaxon/>
WHERE
{
 { 
   SELECT REPLACE(str(?gold),"http://genomesonline.org/cgi-bin/GOLD/GOLDCards.cgi\\?goldstamp=", "GOLD:" ) as ?label ?gold as ?link 
   FROM <http://togogenome.org/gold/>
   WHERE 
   {
    ?gold mccv:MCCV_000020 idtax:1148 .
   }
 }
 UNION
 { 
   SELECT DISTINCT ?label ?xref as ?link
   FROM <http://togogenome.org/refseq/>
   WHERE
   {
     values ?tax_id { idtax:1148 }
     values ?so { obo:SO_0000340 obo:SO_0000155 }
     ?seq rdfs:seeAlso ?tax_id .
     ?seq a ?so .
     ?seq rdfs:seeAlso ?xref .
     ?xref rdfs:label ?label .
   } ORDER BY ?label
 }
}

実行結果

  • 菌株リストを取得(東工大のエンドポイントができればグラフ名変更)
PREFIX mccv: <http://purl.jp/bio/01/mccv#>

SELECT DISTINCT ?label ?strain_id as ?link 
FROM <http://microbedb.jp/mccv/>
WHERE 
{
 VALUES ?related {mccv:MCCV_000056 mccv:MCCV_000022 mccv:MCCV_000057 mccv:MCCV_000023} 
 ?strain_id ?related <http://identifiers.org/taxonomy/228599> .
 OPTIONAL { ?strain_id mccv:MCCV_000010 ?label . }
} ORDER BY ?label

phenotype_info スタンザ

生物種の表現型 + MPOから growth temprature なども

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX up: <http://purl.uniprot.org/core/>
PREFIX idtax: <http://purl.uniprot.org/taxonomy/>
 
SELECT ?mpo ?phenotype (GROUP_CONCAT(?value; SEPARATOR = " , ") AS ?value)
FROM <http://togogenome.org/mpo/>
WHERE 
{
  idtax:383372 ?mpo ?o .
  ?mpo rdfs:label ?phenotype .
  FILTER (lang(?phenotype) = "en") .
  OPTIONAL 
  {
    ?o rdfs:label ?o2 .
    FILTER (lang(?o2) = "en") .
  }
  BIND( IF(bound(?o2) ,?o2 , ?o) as ?value )
} GROUP BY ?mpo ?phenotype ORDER BY ?mpo

実行結果

BRC_metadata スタンザ

ある菌株のBRCでの基本情報

PREFIX mccv: <http://purl.jp/bio/01/mccv#>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX idtax: <http://identifiers.org/taxonomy/>

SELECT 
  ?strain_id AS ?strain_url ?strain_no ?strain_name 
  ?related_type ?typeStrain ?application ?history 
  ?ref_id  concat("http://www.nbrc.nite.go.jp/NBRC2/NBRCReferenceDetailServlet?NO=", ?ref_id) AS ?ref_url 
  GROUP_CONCAT(?other_link; SEPARATOR = ", ") AS ?other_links
FROM <http://microbedb.jp/mccv/>
WHERE 
{
  { SELECT DISTINCT ?strain_id GROUP_CONCAT(?related_label; SEPARATOR = ", ") AS ?related_type
    {
      VALUES ?related_type  { mccv:MCCV_000056 mccv:MCCV_000022 mccv:MCCV_000057 mccv:MCCV_000023}
      ?strain_id ?related_type  idtax:228599 .
      ?related_type rdfs:label ?related_label FILTER (lang(?related_label) = "en")  .
    }
  }
  OPTIONAL { ?strain_id mccv:MCCV_000010 ?strain_no . }
  OPTIONAL { ?strain_id mccv:MCCV_000012 ?strain_name . }
  OPTIONAL { ?strain_id mccv:MCCV_000017 ?typeStrain . }
  OPTIONAL { ?strain_id mccv:MCCV_000033 ?application . }
  OPTIONAL { ?strain_id mccv:MCCV_000027 ?history . }
  OPTIONAL { ?strain_id mccv:MCCV_000024/mccv:MCCV_000026 ?other_link . }
  OPTIONAL 
  {
    ?strain_id dcterms:references/mccv:MCCV_000047 ?ref_id
  }
}

BRC_synonym スタンザ

ある菌株のBRCでのsynonym情報

BRC metadata

BRC_reference スタンザ

ある菌株のBRCでの文献情報


ortholog_taxon_profile スタンザ

あるオーソログを所持する株が他より多く存在する系統群


taxon_ortholog_profile スタンザ

系統群に含まれるオーソログの組成


pathogen_info スタンザ

ある系統がどのような感染症を引き起こすか

PREFIX pdo: <http://purl.jp/bio/11/pdo/>
PREFIX ncbitaxon: <http://purl.obolibrary.org/obo/>

SELECT ?bacterialName (GROUP_CONCAT(?diseaseName; SEPARATOR = ", ") AS ?diseaseNameSet) ?infectiousType ?strainType
FROM <http://microbedb.jp/pdo/>
FROM <http://microbedb.jp/pdo_csso_mapping/>
FROM <http://togogenome.org/ncbitaxon/>
WHERE
{
  { ?tax_id rdfs:subClassOf+ ncbitaxon:NCBITaxon_1763 }
  UNION
  { ?tax_id rdfs:label ?o FILTER (?tax_id = ncbitaxon:NCBITaxon_1763) }
  ?tax_id rdfs:label ?bacterialName ;
    pdo:isAssociatedTo ?blank .
  ?blank ?p ?disease FILTER (?p IN(pdo:mayCaused, pdo:isRelatedTo)).
  ?disease rdfs:label ?diseaseName .
  OPTIONAL { ?tax_id pdo:isAssociatedTo/pdo:infectiousType ?infectiousType . }
  OPTIONAL { ?tax_id pdo:isAssociatedTo/pdo:strainType ?strainType . }
}

※ORDER BY ?bacterialName を最後につけると、?bacterialNameの値が全て同一になる。Virtuosoのバグ?

gazetter

ある環境に紐付けられたgoldサンプルの地理情報

PREFIX meo: <http://purl.jp/bio/11/meo/> 
PREFIX gold: <http://www.genomesonline.org/cgi-bin/GOLD/GOLDCards.cgi?goldstamp=> 

SELECT 
 ?gaz_id ?place_name
 ?gold REPLACE(STR(?gold),"http://www.genomesonline.org/cgi-bin/GOLD/GOLDCards.cgi\\?goldstamp=","") AS ?gold_id 
FROM <http://togogenome.org/gold_meo0_5test/>
FROM <http://togogenome.org/meov0_5test/>
FROM <http://togogenome.org/gazetteer/>
{
  {
    SELECT DISTINCT IRI(REPLACE(STR(?gaz),"http://purl.bioontology.org/ontology/GAZ/","http://purl.obolibrary.org/obo/")) AS ?gaz_id ?gold
    {
      ?meo_id rdfs:subClassOf* meo:MEO_0000029.
      ?gold meo:MEO_0000437  ?meo_id.
      ?gold meo:MEO_0000438 ?gaz .
    }GROUP BY ?gaz
  }
  ?gaz_id rdfs:label ?place_name
}_id rdfs:label ?place_name
}

Environment関連スタンザ

MEOIDを指定するスタンザ

environment_attributes スタンザ

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX meo: <http://purl.jp/bio/11/meo/>

SELECT ?meo_id ?meo_term_label ?meo_definition ?meo_superclass_id ?meo_superclass_term_label
FROM <http://microbedb.jp/meo/>
WHERE
{
  meo:MEO_0000029 rdfs:label ?meo_term_label .
  ?meo_id rdfs:label ?meo_term_label .
  OPTIONAL { ?meo_id  meo:definition ?meo_definition . }
  OPTIONAL 
  { 
    ?meo_id rdfs:subClassOf ?meo_superclass_id . 
    ?meo_superclass_id rdfs:label ?meo_superclass_term_label .
  }
} 

ontology_viewer スタンザ

オントロジーを階層的に表示するビューアー
MEOオントロジー

PREFIX meo: <http://purl.jp/bio/11/meo/>

SELECT ?meo_id ?label ?definition ?parent
FROM <http://togogenome.org/meov0_5test/> #temporary
WHERE 
{
 ?meo_id a owl:Class .
 OPTIONAL {?meo_id rdfs:label ?label}
 OPTIONAL {?meo_id meo:definition ?definition}
 OPTIONAL {?meo_id rdfs:subClassOf ?parent}
}

実行結果

PDOオントロジー

PREFIX obo: <http://purl.obolibrary.org/obo/>

SELECT ?pdo_id ?parent ?label ?definition
FROM <http://microbedb.jp/pdo/>
WHERE
{
  ?pdo_id a owl:Class .
  OPTIONAL {?pdo_id rdfs:subClassOf ?parent}
  OPTIONAL {?pdo_id rdfs:label ?label}
  OPTIONAL {?pdo_id obo:IAO_0000115 ?definition}
}

実行結果

metagenome_sample_list スタンザ

ある環境(meo:MEO_0000054)から採取されたメタゲノムサンプルのリスト

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT 
  ?srs_id REPLACE(STR(?srs_id),"http://www.ncbi.nlm.nih.gov/sra/","") AS ?srs_no
  ?description (GROUP_CONCAT(?meo_label ; SEPARATOR = ", ")AS ?environment)
FROM <http://microbedb.jp/srs/>
FROM <http://microbedb.jp/metagenome_mapping/>
FROM <http://togogenome.org/meov0_5test/> #temporary
WHERE
{
  {
    SELECT DISTINCT ?srs_id
    WHERE
    {
      ?meo_id rdfs:subClassOf* meo:MEO_0000054 .
      ?srs_id meo:MEO_0000441 "metagenome" .
      ?srs_id meo:MEO_0000437 ?meo_id .
    }
  }
  OPTIONAL { ?srs_id srs:TITLE ?description . }
  OPTIONAL 
  {
    ?srs_id meo:MEO_0000437 ?meo .
    ?meo rdfs:label ?meo_label .
  }
}GROUP BY ?srs_id ?description

meta16s_sample_list スタンザ

ある環境(meo:MEO_0000029)から採取されたメタ16Sゲノムサンプルのリスト

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT 
  ?srs_id REPLACE(STR(?srs_id),"http://www.ncbi.nlm.nih.gov/sra/","") AS ?srs_no
  ?description (GROUP_CONCAT(?meo_label ; SEPARATOR = ", ")AS ?environment)
FROM <http://microbedb.jp/srs/>
FROM <http://microbedb.jp/metagenome_mapping/>
FROM <http://togogenome.org/meov0_5test/> #temporary
WHERE
{
  {
    SELECT DISTINCT ?srs_id
    WHERE
    {
      ?meo_id rdfs:subClassOf* meo:MEO_0000029 .
      ?srs_id meo:MEO_0000441 "meta 16S" .
      ?srs_id meo:MEO_0000437 ?meo_id .
    }
  }
  OPTIONAL { ?srs_id srs:TITLE ?description . }
  OPTIONAL 
  {
    ?srs_id meo:MEO_0000437 ?meo .
    ?meo rdfs:label ?meo_label .
  }
}GROUP BY ?srs_id ?description 

meta16S_sample_list スタンザ

ある環境から採取されたメタ16Sサンプルのリスト


Metagenome関連スタンザ

SRSIDを指定するスタンザ

metagenome_sample_attributes スタンザ

そのメタゲノム/メタ16Sサンプルの基本情報


metagenome_reference スタンザ

そのメタゲノム/メタ16Sサンプルの関連論文


metagenome_cross_reference スタンザ

そのメタゲノム/メタ16Sサンプルの他DBへのLink情報

PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>

SELECT ?srs_id REPLACE(STR(?srs_id), "http://www.ncbi.nlm.nih.gov/sra/", "") AS ?srs_label ?title
FROM <http://microbedb.jp/srs/>
WHERE
{
   ?srs_id srs:TITLE ?title FILTER (?srs_id = srs:SRS182953) .
}

meta16s_taxonomy_compositon スタンザ

オントロジー検索での集計結果ttl出力用CONSTRUCT

SELECT ?meo_id
FROM <http://microbedb.jp/meo/>
WHERE
{
 ?meo_id a <http://www.w3.org/2002/07/owl#Class>
}
DEFINE output:format "NT"
PREFIX meo:<http://purl.jp/bio/11/meo/>

CONSTRUCT
{ 
  meo:MEO_0000029 meo:tax_comp_via16s_ontology 
  [
    ?tax_rank ?taxon;
    meo:comp_sum ?tax_cnt;
  ]. 
}
FROM <http://microbedb.jp/srs/>
FROM <http://microbedb.jp/meta16S_env/> 
FROM <http://microbedb.jp/meo/>
WHERE
{
  SELECT ?taxon SUM(?count) AS ?tax_cnt ?tax_rank 
  FROM <http://microbedb.jp/srs/>
  FROM <http://microbedb.jp/meta16S_env/> 
  FROM <http://microbedb.jp/meo/>
  WHERE
  {
    values ?tax_rank { meo:MEO_0000431 meo:MEO_0000432 meo:MEO_0000433 meo:MEO_0000434 meo:MEO_0000435 meo:MEO_0000436 }
    ?meo_id rdfs:subClassOf* meo:MEO_0000029 .
    ?srs meo:MEO_0000437 ?meo_id .
    ?srs meo:MEO_0000429 ?blank .
    ?blank ?tax_rank ?taxon FILTER ((STRSTARTS(STR(?taxon), "http://purl.obolibrary.org/obo/NCBITaxon_"))).
    ?blank meo:MEO_0000430 ?count.
  }GROUP BY ?taxon ?tax_rank 
}

※上記CONSTRUCT文で、FROM <http://microbedb.jp/meta16S_env/> を FROM <http://microbedb.jp/meta16S_human/>に変えたものを作成する

メタ16SでのTaxonomyCompositionの集計)
meo:MEO_0000029(hot spring環境)
meo:MEO_0000436(Domain 単位)集計)
meo:MEO_0000435(Phylum 単位)集計)
meo:MEO_0000434(Class 単位)集計)
meo:MEO_0000433(Order 単位)集計)
meo:MEO_0000432(Family 単位)集計)
meo:MEO_0000431(Genus 単位)集計)

PREFIX meo:<http://purl.jp/bio/11/meo/>

SELECT ?label ?tax_cnt
FROM <http://microbedb.jp/metagenome_mapping/>
FROM <http://microbedb.jp/meta16s_env_tax_count/>
FROM <http://togogenome.org/ncbitaxon/>
WHERE
{
  {
    SELECT
      IRI(REPLACE(str(?tax),"http://identifiers.org/taxonomy/","http://purl.obolibrary.org/obo/NCBITaxon_")) AS ?taxon SUM(?count) AS ?tax_cnt
    WHERE
    {
      ?srs meo:MEO_0000437 meo:MEO_0000029 .
      ?srs meo:MEO_0000429 ?blank .
      ?blank meo:MEO_0000434 ?tax FILTER (STRSTARTS(STR(?tax), "http://identifiers.org/taxonomy/")).
      ?blank meo:MEO_0000430 ?count.
    } GROUP BY ?tax
  }
  ?taxon rdfs:label ?label
} ORDER BY DESC 2

sample_taxonomy_compositon_via_meta16s スタンザ

PREFIX srs: <http://www.ncbi.nlm.nih.gov/sra/>
PREFIX meo:<http://purl.jp/bio/11/meo/>

SELECT ?label ?tax_cnt
FROM <http://microbedb.jp/metagenome_mapping/>
FROM <http://microbedb.jp/meta16s_env_tax_count/>
FROM <http://microbedb.jp/meta16s_human_tax_count/>
FROM <http://togogenome.org/ncbitaxon/>
{
  {
    SELECT
      IRI(REPLACE(str(?tax),"http://identifiers.org/taxonomy/","http://purl.obolibrary.org/obo/NCBITaxon_")) AS ?taxon SUM(?count) AS ?tax_cnt
    WHERE
    {
      ?srs meo:MEO_0000429 ?blank FILTER(?srs = srs:SRS334046) .
      ?blank meo:MEO_0000434 ?tax FILTER (STRSTARTS(STR(?tax), "http://identifiers.org/taxonomy/")).
      ?blank meo:MEO_0000430 ?count.
    } GROUP BY ?tax
  }
  ?taxon rdfs:label ?label
}ORDER BY DESC 2

その他のスタンザ

disease_info スタンザ

病気と関連する生物種などの情報

PREFIX pdo: <http://purl.jp/bio/11/pdo/>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX csso: <http://purl.jp/bio/11/csso/> 

SELECT ?diseaseName ?synonymList ?def ?className ?symptomList
FROM <http://microbedb.jp/pdo/>
FROM <http://microbedb.jp/csso/>
FROM <http://microbedb.jp/pdo_csso_mapping/>
WHERE
{
  pdo:PDO_000173 rdfs:label ?diseaseName .
  {
    SELECT (GROUP_CONCAT(?synonym; SEPARATOR = " , ") AS ?synonymList)
    WHERE
    {
      pdo:PDO_000173 skos:altLabel ?synonym .
    }
  }
  {
    SELECT (GROUP_CONCAT(?symptoms; SEPARATOR = " , ") AS ?symptomList)
    WHERE
    {
      pdo:PDO_000173 pdo:hasSymptomOf ?symptom .
      ?symptom rdfs:label ?symptoms .
    }
  }
  OPTIONAL { pdo:PDO_000173 obo:IAO_0000115 ?def. }
  OPTIONAL
  {
    pdo:PDO_000173 rdfs:subClassOf+ ?upperClass .
    ?upperClass rdfs:subClassOf pdo:PDO_000001 .
    ?upperClass rdfs:label ?className .
  }
}

可視化スタンザ

environment_taxonomy_composition スタンザ

ある環境に含まれている生物種の情報

PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX mccv: <http://purl.jp/bio/01/mccv#>

SELECT ?tax
FROM <http://togogenome.org/gold/>
FROM <http://togogenome.org/meo/>
WHERE
{
  ?gold meo:environmentalDescribed meo:MEO_0000033 .
  ?gold mccv:MCCV_000020 ?tax .
}
PREFIX taxon:<http://purl.obolibrary.org/obo/NCBITaxon_>
PREFIX taxon2:<http://purl.obolibrary.org/obo/ncbitaxon#>

SELECT ?tax ?cnt ?tax_label ?parent ?rank
FROM <http://togogenome.org/ncbitaxon/>
WHERE 
{
 {
  SELECT ?tax count(?tax) as ?cnt
  {
   ?search_tax rdfs:label ?tmp FILTER (?search_tax IN (taxon:1005395, taxon:1007104, (中略) taxon:984262, taxon:993516, taxon:993517)).
   ?search_tax rdfs:subClassOf* ?tax.
  }GROUP BY ?tax
 }
 ?tax rdfs:label ?tax_label.
 OPTIONAL { ?tax rdfs:subClassOf ?parent }.
 OPTIONAL { ?tax taxon2:has_rank ?rank}.
}

organism plot スタンザ

genomeサイズ + Organism Name + Phenotype

DEFINE sql:select-option "order"
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX mccv: <http://purl.jp/bio/01/mccv#>
PREFIX mpo:<http://purl.jp/bio/01/mpo#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX insdc: <http://insdc.org/owl/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

SELECT  
  ?tax ?organism_name ?bioProject ?genome_length 
  (sql:GROUP_DIGEST (?cell_shape_label, ', ', 1000, 1)) AS ?cell_shape_label
  (sql:GROUP_DIGEST (?temp_range_label, ', ', 1000, 1)) AS ?temp_range_label
  (sql:GROUP_DIGEST (?oxy_req_label, ', ', 1000, 1)) AS ?oxy_req_label
  ?opt_temp ?min_temp ?max_temp ?opt_ph ?min_ph ?max_ph
FROM <http://togogenome.org/refseq/>
FROM <http://togogenome.org/mpo/> #TODO change to gold
FROM <http://togogenome.org/ncbitaxon/>
{
  {
    SELECT  ?tax ?bioProject SUM(?seq_len) AS ?genome_length IRI(REPLACE(str(?tax),"http://identifiers.org/taxonomy/","http://purl.obolibrary.org/obo/NCBITaxon_")) AS ?taxon
    FROM <http://togogenome.org/refseq/>
    WHERE
    {
      ?tax rdf:type idorg:Taxonomy .
      ?seq rdfs:seeAlso ?tax ;
      rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
      ?seq insdc:sequence_length ?seq_len ;
        rdfs:seeAlso ?bioProject.
      ?bioProject rdf:type idorg:BioProject .
    } GROUP BY ?tax  ?bioProject
  }
  OPTIONAL { ?tax mpo:MPO_10001/rdfs:label ?cell_shape_label  FILTER (lang(?cell_shape_label) = "en") .}
  OPTIONAL { ?tax mpo:MPO_10003/rdfs:label ?temp_range_label  FILTER (lang(?temp_range_label) = "en") .}
  OPTIONAL { ?tax mpo:MPO_10002/rdfs:label ?oxy_req_label FILTER (lang(?oxy_req_label) = "en") .}
  OPTIONAL { ?tax mpo:MPO_10009 ?opt_temp .}
  OPTIONAL { ?tax mpo:MPO_10010 ?min_temp .}
  OPTIONAL { ?tax mpo:MPO_10011 ?max_temp .}
  OPTIONAL { ?tax mpo:MPO_10005 ?opt_ph .}
  OPTIONAL { ?tax mpo:MPO_10006 ?min_ph .}
  OPTIONAL { ?tax mpo:MPO_10007 ?max_ph .}
  ?taxon rdfs:label ?organism_name
} GROUP BY ?tax ?organism_name ?genome_length  ?bioProject  ?opt_temp ?min_temp ?max_temp ?opt_ph ?min_ph ?max_ph

gene数

DEFINE sql:select-option "order"
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX insdc: <http://insdc.org/owl/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

SELECT  ?tax ?bioProject count(?gene) as ?num_gene 
FROM <http://togogenome.org/refseq/>
WHERE
{
  ?tax rdf:type idorg:Taxonomy .
  ?seq rdfs:seeAlso ?tax ;
    rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
  ?seq  rdfs:seeAlso ?bioProject.
  ?bioProject rdf:type idorg:BioProject .
  ?gene obo:so_part_of ?seq ; rdf:type obo:SO_0000704 . 
} GROUP BY ?tax ?bioProject

rRNA数

DEFINE sql:select-option "order"
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX insdc: <http://insdc.org/owl/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

SELECT ?tax ?bioProject COUNT(?rrna) AS ?num_rrna
FROM <http://togogenome.org/refseq/>
WHERE
{
  ?tax rdf:type idorg:Taxonomy .
  ?seq rdfs:seeAlso ?tax ;
    rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
  ?seq rdfs:seeAlso ?bioProject.
  ?bioProject rdf:type idorg:BioProject .  
  ?rrna obo:so_part_of ?seq ; rdf:type obo:SO_0000252 . 
} GROUP BY ?tax ?bioProject

tRNA数

DEFINE sql:select-option "order"
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX insdc: <http://insdc.org/owl/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

SELECT ?tax ?bioProject COUNT(?trna) AS ?num_trna
FROM <http://togogenome.org/refseq/>
WHERE
{
  ?tax rdf:type idorg:Taxonomy .
  ?seq rdfs:seeAlso ?tax ;
    rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
  ?seq rdfs:seeAlso ?bioProject.
  ?bioProject rdf:type idorg:BioProject .  
  ?trna obo:so_part_of ?seq ; rdf:type obo:SO_0000253 . 
} GROUP BY ?tax ?bioProject

環境名

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX mccv: <http://purl.jp/bio/01/mccv#>

SELECT  ?tax (sql:GROUP_DIGEST (?label, ', ', 1000, 1)) as ?habitat 
FROM <http://togogenome.org/gold/>
FROM <http://togogenome.org/meo/>
WHERE
{
 ?gold mccv:MCCV_000020 ?tax FILTER regex(?tax, "^http://identifiers.org/") .
 ?gold meo:environmentalDescribed ?meo .
 ?meo a owl:Class ;
   rdfs:label ?label.
} GROUP BY ?tax

環境名(MEO v0.5対応 第一階層のみを取得)

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX meo: <http://purl.jp/bio/11/meo/>
PREFIX mccv: <http://purl.jp/bio/01/mccv#>

SELECT  ?tax (sql:GROUP_DIGEST (?label, ', ', 1000, 1)) as ?habitat 
FROM <http://togogenome.org/gold/>
FROM <http://togogenome.org/gold_meo0_5test/> #temporary
FROM <http://togogenome.org/meov0_5test/> #temporary
WHERE
{
 ?gold mccv:MCCV_000020 ?tax FILTER regex(?tax, "^http://identifiers.org/") .
 ?gold meo:MEO_0000437 ?meo .
 ?meo a owl:Class ;
   rdfs:subClassOf* ?parent .
   ?parent rdfs:label ?label.
 ?parent meo:MEO_0000442 "1"
} GROUP BY ?tax


Gene数集計用CONSTRUCT

DEFINE sql:select-option "order"
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX insdc: <http://insdc.org/owl/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

CONSTRUCT
{ ?tax obo:genome_count [
  rdfs:seeAlso ?bioProject;
  obo:gene_cnt ?num_gene;
  obo:rrna_cnt ?num_rrna;
  obo:trna_cnt ?num_trna;
 ]. }
FROM <http://togogenome.org/refseq/>
WHERE
{
 SELECT ?tax ?bioProject COUNT(?gene) as ?num_gene COUNT(?rrna) AS ?num_rrna COUNT(?trna) AS ?num_trna
 FROM <http://togogenome.org/refseq/>
 WHERE
 {
  ?tax rdf:type idorg:Taxonomy .
  ?seq rdfs:seeAlso ?tax ;
    rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
  ?seq rdfs:seeAlso ?bioProject.
  ?bioProject rdf:type idorg:BioProject .  
  { ?gene obo:so_part_of ?seq ; rdf:type obo:SO_0000704 . }
  UNION
  { ?rrna obo:so_part_of ?seq ; rdf:type obo:SO_0000252 . }
  UNION
  { ?trna obo:so_part_of ?seq ; rdf:type obo:SO_0000253 .  }
 } GROUP BY ?tax ?bioProject
}

Gene数集計用CONSTRUCT(tax,bioproject毎)

tax、bioprojectのリスト出力

PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

SELECT DISTINCT ?tax ?bioProject
FROM <http://microbedb.jp/refseq/>
WHERE
{
  ?tax rdf:type idorg:Taxonomy .
  ?seq rdfs:seeAlso ?tax ;
    rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
  ?seq rdfs:seeAlso ?bioProject.
  ?bioProject rdf:type idorg:BioProject .
}

tax=1148 bioproject=57659の集計

DEFINE sql:select-option "order"
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX idorg:<http://rdf.identifiers.org/database/>

CONSTRUCT
{ ?tax obo:genome_count [
  rdfs:seeAlso ?bioProject;
  obo:gene_cnt ?num_gene;
  obo:rrna_cnt ?num_rrna;
  obo:trna_cnt ?num_trna;
 ]. }
FROM <http://microbedb.jp/refseq/>
WHERE
{
 SELECT ?tax ?bioProject COUNT(?gene) as ?num_gene COUNT(?rrna) AS ?num_rrna COUNT(?trna) AS ?num_trna
 FROM <http://microbedb.jp/refseq/>
 WHERE
 {
  ?seq rdfs:seeAlso ?tax FILTER (?tax = <http://identifiers.org/taxonomy/1148>) .
  ?seq rdf:type ?obo_type FILTER(?obo_type IN (obo:SO_0000340, obo:SO_0000155 )).
  ?seq rdfs:seeAlso ?bioProject FILTER (?bioProject = <http://identifiers.org/bioproject/57659>).
  { ?gene obo:so_part_of ?seq ; rdf:type obo:SO_0000704 . }
  UNION
  { ?rrna obo:so_part_of ?seq ; rdf:type obo:SO_0000252 . }
  UNION
  { ?trna obo:so_part_of ?seq ; rdf:type obo:SO_0000253 .  }
 }
}

Gene数集計結果SELECT文

SELECT ?tax ?project_id ?num_gene ?num_rrna ?num_trna
FROM <http://togogenome.org/refseq_gene_count/>
WHERE
{
 ?tax <gene_count> ?blank .
 ?blank rdfs:seeAlso ?project_id .
 ?blank <gene_number> ?num_gene .
 ?blank <rrna_number> ?num_rrna .
 ?blank <trna_number> ?num_trna .
}

pfam plot スタンザ

pfamID取得

PREFIX up: <http://purl.uniprot.org/core/>
PREFIX taxonomy: <http://purl.uniprot.org/taxonomy/>
PREFIX dct:   <http://purl.org/dc/terms/>

SELECT DISTINCT  REPLACE(STR(?ref), "http://purl.uniprot.org/pfam/","") AS ?pfam_id 
FROM <http://togogenome.org/uniprot/>
WHERE 
{
  ?protein up:organism taxonomy:103690 ;
    rdfs:seeAlso <http://purl.uniprot.org/refseq/NP_485497.1> .
  ?protein rdfs:seeAlso ?ref .
  ?ref up:database ?database .
  ?database up:abbreviation ?abbr
  FILTER (?abbr ='Pfam').
}

pfam名

PREFIX pfam: <http://purl.uniprot.org/pfam/>

SELECT ?label
FROM <http://togogenome.org/uniprot/>
WHERE
{
  pfam:PF00400 rdfs:comment ?label .
}

genomeサイズ + Organism Name + Phenotype
環境名
Gene数集計結果SELECT文
※Organism plotと同じ

指定したpfamを持つTaxonomyと、pfamのヒット数、Protein数

PREFIX up: <http://purl.uniprot.org/core/>
PREFIX tax: <http://purl.uniprot.org/taxonomy/>
PREFIX pfam: <http://purl.uniprot.org/pfam/>

SELECT 
  REPLACE(STR(?tax), "http://purl.uniprot.org/taxonomy/", "http://identifiers.org/taxonomy/") AS ?tax_id
  (SUM(?hits) as ?num_pfam)
  (COUNT(DISTINCT(?prot_id)) AS ?num_pfam_protein)
FROM <http://togogenome.org/uniprot/>
WHERE
{
  ?prot_id up:organism ?tax .
  ?prot_id rdfs:seeAlso pfam:PF00400 .
  ?id rdf:subject ?prot_id .
  ?id rdf:object pfam:PF00400 .
  ?id up:hits ?hits .
} GROUP BY ?tax

以下、参考
geneに含まれるPFAMの種類の最大値を調べるクエリ

PREFIX up: <http://purl.uniprot.org/core/>
PREFIX taxonomy: <http://purl.uniprot.org/taxonomy/>
PREFIX dct:   <http://purl.org/dc/terms/>

SELECT DISTINCT  ?gene COUNT(?ref) AS ?pfam_id_cnt 
FROM <http://togogenome.org/uniprot/>
WHERE 
{
  ?protein up:organism ?taxonomy ;
    rdfs:seeAlso ?gene . #<http://purl.uniprot.org/refseq/NP_485497.1> .
   ?gene up:database <http://purl.uniprot.org/database/RefSeq> .
  ?protein rdfs:seeAlso ?ref .
  ?ref up:database ?database .
  ?database up:abbreviation ?abbr
  FILTER (?abbr ='Pfam').
} GROUP BY ?taxonomy ?gene ORDER BY DESC 2

複数種のPFAMを持つgene

PREFIX up: <http://purl.uniprot.org/core/>
PREFIX taxonomy: <http://purl.uniprot.org/taxonomy/>
PREFIX dct:   <http://purl.org/dc/terms/>

SELECT DISTINCT ?gene COUNT(?ref) AS ?pfam_id_cnt 
FROM <http://togogenome.org/uniprot/>
WHERE 
{
  ?protein up:organism taxonomy:103690 ;
    rdfs:seeAlso ?gene . #<http://purl.uniprot.org/refseq/NP_486719.1> .
   ?gene up:database <http://purl.uniprot.org/database/RefSeq> .
  ?protein rdfs:seeAlso ?ref .
  ?ref up:database ?database .
  ?database up:abbreviation ?abbr
  FILTER (?abbr ='Pfam').
}GROUP BY ?gene ORDER BY DESC 2
taxid:103690
geneid:alr3431

taxonomy treeスタンザ

PREFIX taxon: <http://purl.obolibrary.org/obo/NCBITaxon_>
PREFIX taxon_rank: <http://purl.obolibrary.org/obo/ncbitaxon#>

SELECT ?tax ?parent ?tax_label ?rank
FROM <http://togogenome.org/ncbitaxon/>
WHERE
{
  {
    ?search_tax rdfs:label ?label FILTER (?search_tax = taxon:1148 ) .
    ?search_tax rdfs:subClassOf* ?tax.
    ?tax rdfs:label ?tax_label .
    OPTIONAL { ?tax rdfs:subClassOf ?parent . }
    OPTIONAL { ?tax taxon_rank:has_rank ?rank . }
  }
  UNION
  {
    ?search_tax rdfs:label ?label FILTER (?search_tax = taxon:1148) .
    ?tax rdfs:subClassOf ?search_tax .
    ?tax rdfs:label ?tax_label .
    OPTIONAL { ?tax rdfs:subClassOf ?parent . }
    OPTIONAL { ?tax taxon_rank:has_rank ?rank . }
  }
}

新taxonomy.owl対応

PREFIX taxo: <http://ddbj.nig.ac.jp/ontologies/taxonomy#>
PREFIX taxid: <http://identifiers.org/taxonomy/>

SELECT ?tax ?parent ?tax_label ?rank
FROM <http://togogenome.org/taxonomy/>
WHERE
{
  {
    ?search_tax rdfs:label ?label FILTER (?search_tax = taxid:1148 ) .
    ?search_tax rdfs:subClassOf* ?tax.
    ?tax rdfs:label ?tax_label .
    OPTIONAL { ?tax rdfs:subClassOf ?parent . }
    OPTIONAL { ?tax taxo:rank ?rank . }
  }
  UNION
  {
    ?search_tax rdfs:label ?label FILTER (?search_tax = taxid:1148) .
    ?tax rdfs:subClassOf ?search_tax .
    ?tax rdfs:label ?tax_label .
    OPTIONAL { ?tax rdfs:subClassOf ?parent . }
    OPTIONAL { ?tax taxo:rank ?rank . }
  }
}
個人用ツール